/ [cpio] / cpio / sysdep.m4
To checkout: cvs -d:pserver:anonymous@cvs.gnu.org.ua:/cvsmirror/cpio co cpio/sysdep.m4
Puszcza

Contents of /cpio/sysdep.m4

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.1 - (show annotations)
Fri Feb 8 09:28:51 2008 UTC (13 years, 8 months ago) by gray
Branch: MAIN
CVS Tags: HEAD
Fix mingw build. Thanks to Robert Millan.

* NEWS, THANKS: Update.
* bootstrap: Create lib/system.c, m4/sysdep.m4, update lib/system.h.
* mingw.m4, sysdep.m4: New files.
* configure.ac: Raise version number to 2.9.90.
Call CPIO_SYSDEP. Remove the call to gl_USE_SYSTEM_EXTENSIONS.
(AC_CHECK_HEADERS): Add process.h sys/ioctl.h
* lib/Makefile.am (libcpio_a_SOURCES): Add system.c
* src/idcache.c: Include system.h
* src/userspec.c: Remove alloca stuff (already handled by
gnulib). Include alloca.h.
Remove useless declarations of get.* functions.
* src/util.c: Include sys/ioctl.h conditionally.

1 divert(-1)
2 # System dependent functions for GNU cpio.
3 #
4 # Copyright (C) 2007 Free Software Foundation, Inc.
5 # GNU cpio is free software; you can redistribute it and/or modify
6 # it under the terms of the GNU General Public License as published by
7 # the Free Software Foundation; either version 3, or (at your option)
8 # any later version.
9 #
10 # GNU cpio is distributed in the hope that it will be useful,
11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
13 # GNU General Public License for more details.
14 #
15 # You should have received a copy of the GNU General Public License
16 # along with GNU cpiio. If not, see <http://www.gnu.org/licenses/>.
17
18 undef(`include')
19
20 ifelse(MODE,`AC',`
21
22 define(`FUNCLIST')
23
24 define(`BEGIN')
25 define(`END',`divert(0)dnl
26 # -*- buffer-read-only: t -*- vi: set ro:
27 # THIS FILE IS GENERATED AUTOMATICALLY. PLEASE DO NOT EDIT.
28 AC_DEFUN([CPIO_SYSDEP],[AC_CHECK_FUNCS([FUNCLIST])])')
29
30 dnl MAKESTUB(type, name, args...)
31 define(`MAKESTUB',`define(`FUNCLIST',FUNCLIST` $2')')
32
33 ',MODE,`H',`
34 changecom(/*,*/)
35 define(`ROHEADER',`/* -*- buffer-read-only: t -*- vi: set ro:
36 THIS FILE IS GENERATED AUTOMATICALLY. PLEASE DO NOT EDIT.
37 */')
38
39 define(`BEGIN')
40 define(`END')
41
42 dnl MAKESTUB(type, name, args...)
43 define(`MAKESTUB',`
44 `#ifndef HAVE_'translit($2, `a-z-', `A-Z_')
45 $1 $2 (ifelse($#,2,`void',`shift(shift($@))'));
46 #endif
47 ')
48
49 divert(0)dnl
50 ROHEADER
51 ',MODE,`C',`
52 changecom(/*,*/)
53 define(`ROHEADER',`/* -*- buffer-read-only: t -*- vi: set ro:
54 THIS FILE IS GENERATED AUTOMATICALLY. PLEASE DO NOT EDIT.
55 */')
56
57 define(`BEGIN')
58 define(`END')
59
60 define(`__make_unused_args',`dnl
61 $1 __attribute__ ((unused))dnl
62 ifelse($#,1,,`, __make_unused_args(shift($@))')')
63
64 define(`__makeargs',`ifelse($1,`',`void',`__make_unused_args($@)')')
65
66 define(`INTRETVAL',-1)
67
68 dnl MAKESTUB(type, name, args...)
69 define(`MAKESTUB',`
70 `#ifndef HAVE_'translit($2, `a-z-', `A-Z_')
71 # warning "Providing stub placeholder for $2 function"
72 $1
73 $2 (__makeargs(shift(shift($@))))
74 {
75 errno = ENOSYS;
76 return ifelse($1,`int',INTRETVAL,NULL);
77 }
78 #endif`'dnl
79 define(`INTRETVAL',-1)dnl
80 ')
81
82 divert(0)dnl
83 ROHEADER
84 ')

Send suggestions and bug reports to Sergey Poznyakoff
ViewVC Help
Powered by ViewVC 1.1.20